home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 / Ham Radio 2000.iso / ham2000 / misc / sspice10 / cmos.cir next >
Text File  |  1991-02-01  |  1KB  |  29 lines
  1. Allen and Holberg CMOS Op-Amp
  2. ML1 4 2 3 3 NMOS1 W=43U L=10U AD=0.3N AS=0.3N PD=50U PS=50U
  3. ML2 5 1 3 3 NMOS1 W=43U L=10U AD=0.3N AS=0.3N PD=50U PS=50U
  4. ML3 4 4 8 8 PMOS1 W=10U L=10U AD=0.3N AS=0.3N PD=20U PS=20U
  5. ML4 5 4 8 8 PMOS1 W=10U L=10U AD=0.3N AS=0.3N PD=20U PS=20U
  6. ML5 3 7 9 9 NMOS1 W=38U L=10U AD=0.3N AS=0.3N PD=40U PS=40U
  7. ML6 6 5 8 8 PMOS1 W=344U L=10U AD=1.3N AS=1.3N PD=350U PS=350U 
  8. ML7 6 7 9 9 NMOS1 W=652U L=10U AD=2.3N AS=2.3N PD=660U PS=660U
  9. ML8 7 7 9 9 NMOS1 W=38U L=10U AD=0.3N AS=0.3N PD=40U PS=40U
  10. C1 5 6 4.4P
  11. IBIAS 8 7 8.8U
  12. CL 6 0 20P
  13. VDD 8 0 5
  14. VSS 9 0 -5
  15. VIN 1 0 AC 1
  16. VOFF 2 0 0.1M
  17. .MODEL NMOS1 NMOS (VTO=1 KP=17U GAMMA=1.3 LAMBDA=0.01 PHI=0.7
  18. + PB=0.8 MJ=0.5 MJSW=0.3 CGBO=200P CGSO=350P CGDO=350P CJ=300U
  19. + CJSW=500P LD=0.8U TOX=80N)
  20. .MODEL PMOS1 PMOS (VTO=-1 KP=8U GAMMA=0.6 LAMBDA=0.02 PHI=0.6
  21. + PB=0.5 MJ=0.5 MJSW=0.25 CGBO=200P CGSO=350P CGDO=350P CJ=150U
  22. + CJSW=400P LD=0.8U TOX=80N)
  23. .OP
  24. .DC VIN -5M 5M 50U
  25. .AC DEC 20 1 10MEG
  26. .PLOT DC V(6)
  27. .PLOT AC VDB(6)  VP(6)
  28. .END
  29.